home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / zungqr.f < prev    next >
Text File  |  1996-07-19  |  6KB  |  209 lines
  1.       SUBROUTINE ZUNGQR( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
  2. *
  3. *  -- LAPACK routine (version 2.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     September 30, 1994
  7. *
  8. *     .. Scalar Arguments ..
  9.       INTEGER            INFO, K, LDA, LWORK, M, N
  10. *     ..
  11. *     .. Array Arguments ..
  12.       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( LWORK )
  13. *     ..
  14. *
  15. *  Purpose
  16. *  =======
  17. *
  18. *  ZUNGQR generates an M-by-N complex matrix Q with orthonormal columns,
  19. *  which is defined as the first N columns of a product of K elementary
  20. *  reflectors of order M
  21. *
  22. *        Q  =  H(1) H(2) . . . H(k)
  23. *
  24. *  as returned by ZGEQRF.
  25. *
  26. *  Arguments
  27. *  =========
  28. *
  29. *  M       (input) INTEGER
  30. *          The number of rows of the matrix Q. M >= 0.
  31. *
  32. *  N       (input) INTEGER
  33. *          The number of columns of the matrix Q. M >= N >= 0.
  34. *
  35. *  K       (input) INTEGER
  36. *          The number of elementary reflectors whose product defines the
  37. *          matrix Q. N >= K >= 0.
  38. *
  39. *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
  40. *          On entry, the i-th column must contain the vector which
  41. *          defines the elementary reflector H(i), for i = 1,2,...,k, as
  42. *          returned by ZGEQRF in the first k columns of its array
  43. *          argument A.
  44. *          On exit, the M-by-N matrix Q.
  45. *
  46. *  LDA     (input) INTEGER
  47. *          The first dimension of the array A. LDA >= max(1,M).
  48. *
  49. *  TAU     (input) COMPLEX*16 array, dimension (K)
  50. *          TAU(i) must contain the scalar factor of the elementary
  51. *          reflector H(i), as returned by ZGEQRF.
  52. *
  53. *  WORK    (workspace/output) COMPLEX*16 array, dimension (LWORK)
  54. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  55. *
  56. *  LWORK   (input) INTEGER
  57. *          The dimension of the array WORK. LWORK >= max(1,N).
  58. *          For optimum performance LWORK >= N*NB, where NB is the
  59. *          optimal blocksize.
  60. *
  61. *  INFO    (output) INTEGER
  62. *          = 0:  successful exit
  63. *          < 0:  if INFO = -i, the i-th argument has an illegal value
  64. *
  65. *  =====================================================================
  66. *
  67. *     .. Parameters ..
  68.       COMPLEX*16         ZERO
  69.       PARAMETER          ( ZERO = ( 0.0D+0, 0.0D+0 ) )
  70. *     ..
  71. *     .. Local Scalars ..
  72.       INTEGER            I, IB, IINFO, IWS, J, KI, KK, L, LDWORK, NB,
  73.      $                   NBMIN, NX
  74. *     ..
  75. *     .. External Subroutines ..
  76.       EXTERNAL           XERBLA, ZLARFB, ZLARFT, ZUNG2R
  77. *     ..
  78. *     .. Intrinsic Functions ..
  79.       INTRINSIC          MAX, MIN
  80. *     ..
  81. *     .. External Functions ..
  82.       INTEGER            ILAENV
  83.       EXTERNAL           ILAENV
  84. *     ..
  85. *     .. Executable Statements ..
  86. *
  87. *     Test the input arguments
  88. *
  89.       INFO = 0
  90.       IF( M.LT.0 ) THEN
  91.          INFO = -1
  92.       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
  93.          INFO = -2
  94.       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
  95.          INFO = -3
  96.       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  97.          INFO = -5
  98.       ELSE IF( LWORK.LT.MAX( 1, N ) ) THEN
  99.          INFO = -8
  100.       END IF
  101.       IF( INFO.NE.0 ) THEN
  102.          CALL XERBLA( 'ZUNGQR', -INFO )
  103.          RETURN
  104.       END IF
  105. *
  106. *     Quick return if possible
  107. *
  108.       IF( N.LE.0 ) THEN
  109.          WORK( 1 ) = 1
  110.          RETURN
  111.       END IF
  112. *
  113. *     Determine the block size.
  114. *
  115.       NB = ILAENV( 1, 'ZUNGQR', ' ', M, N, K, -1 )
  116.       NBMIN = 2
  117.       NX = 0
  118.       IWS = N
  119.       IF( NB.GT.1 .AND. NB.LT.K ) THEN
  120. *
  121. *        Determine when to cross over from blocked to unblocked code.
  122. *
  123.          NX = MAX( 0, ILAENV( 3, 'ZUNGQR', ' ', M, N, K, -1 ) )
  124.          IF( NX.LT.K ) THEN
  125. *
  126. *           Determine if workspace is large enough for blocked code.
  127. *
  128.             LDWORK = N
  129.             IWS = LDWORK*NB
  130.             IF( LWORK.LT.IWS ) THEN
  131. *
  132. *              Not enough workspace to use optimal NB:  reduce NB and
  133. *              determine the minimum value of NB.
  134. *
  135.                NB = LWORK / LDWORK
  136.                NBMIN = MAX( 2, ILAENV( 2, 'ZUNGQR', ' ', M, N, K, -1 ) )
  137.             END IF
  138.          END IF
  139.       END IF
  140. *
  141.       IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
  142. *
  143. *        Use blocked code after the last block.
  144. *        The first kk columns are handled by the block method.
  145. *
  146.          KI = ( ( K-NX-1 ) / NB )*NB
  147.          KK = MIN( K, KI+NB )
  148. *
  149. *        Set A(1:kk,kk+1:n) to zero.
  150. *
  151.          DO 20 J = KK + 1, N
  152.             DO 10 I = 1, KK
  153.                A( I, J ) = ZERO
  154.    10       CONTINUE
  155.    20    CONTINUE
  156.       ELSE
  157.          KK = 0
  158.       END IF
  159. *
  160. *     Use unblocked code for the last or only block.
  161. *
  162.       IF( KK.LT.N )
  163.      $   CALL ZUNG2R( M-KK, N-KK, K-KK, A( KK+1, KK+1 ), LDA,
  164.      $                TAU( KK+1 ), WORK, IINFO )
  165. *
  166.       IF( KK.GT.0 ) THEN
  167. *
  168. *        Use blocked code
  169. *
  170.          DO 50 I = KI + 1, 1, -NB
  171.             IB = MIN( NB, K-I+1 )
  172.             IF( I+IB.LE.N ) THEN
  173. *
  174. *              Form the triangular factor of the block reflector
  175. *              H = H(i) H(i+1) . . . H(i+ib-1)
  176. *
  177.                CALL ZLARFT( 'Forward', 'Columnwise', M-I+1, IB,
  178.      $                      A( I, I ), LDA, TAU( I ), WORK, LDWORK )
  179. *
  180. *              Apply H to A(i:m,i+ib:n) from the left
  181. *
  182.                CALL ZLARFB( 'Left', 'No transpose', 'Forward',
  183.      $                      'Columnwise', M-I+1, N-I-IB+1, IB,
  184.      $                      A( I, I ), LDA, WORK, LDWORK, A( I, I+IB ),
  185.      $                      LDA, WORK( IB+1 ), LDWORK )
  186.             END IF
  187. *
  188. *           Apply H to rows i:m of current block
  189. *
  190.             CALL ZUNG2R( M-I+1, IB, IB, A( I, I ), LDA, TAU( I ), WORK,
  191.      $                   IINFO )
  192. *
  193. *           Set rows 1:i-1 of current block to zero
  194. *
  195.             DO 40 J = I, I + IB - 1
  196.                DO 30 L = 1, I - 1
  197.                   A( L, J ) = ZERO
  198.    30          CONTINUE
  199.    40       CONTINUE
  200.    50    CONTINUE
  201.       END IF
  202. *
  203.       WORK( 1 ) = IWS
  204.       RETURN
  205. *
  206. *     End of ZUNGQR
  207. *
  208.       END
  209.